各地の天気予報を返信するTwitter botを作る

Twitterでつぶやく

Twitterのアクセストークンを作成する

まずTwitterのサイトで下準備をします。

https://dev.twitter.com/apps からTwitterアカウントでサインインし、「Create a new application」ボタンをクリックして新しいアプリケーションを作成します。

アプリケーションを作成したらSettingsタブを開き、Application TypeのAccess項目で「Read and Write」を選択し、ページ下部の「Update this Twitter application's settings」ボタンをクリックします。

Detailsタブを開き、ページ下部の「Create my access token」ボタンをクリックするとAccess tokenが表示されます。

Access tokenが表示されない場合はページをリロードしてみてください。ページに表示されているConsumer key、Consumer secret、Access token、Access token secretの4つの情報を下のプログラムで使います。

プログラムの作成

ntwitterモジュールをインストールします。

$ npm install ntwitter

以下のプログラムでつぶやきを送信できます。CONSUMER_KEY, CONSUMER_SECRET, ACCESS_TOKEN, ACCESS_TOKEN_SECRETはそれぞれ先ほど取得した値に置き換えてください。

twitter = require "ntwitter"

twit = new twitter
  consumer_key       : "CONSUMER_KEY"
  consumer_secret    : "CONSUMER_SECRET"
  access_token_key   : "ACCESS_TOKEN"
  access_token_secret: "ACCESS_TOKEN_SECRET"

# つぶやく
twit.updateStatus "CoffeeScriptからこんにちは！", (err, data) ->
  if err
    console.log "error: #{err.message}"
  else
    console.log "updated"

重複する内容のつぶやきを連続で送信しようとすると「Status is a duplicate」というエラーが返ってきます。その場合は、内容を変更してつぶやいてみてください。

簡単なTwitter botを作る

「今何時？」というつぶやきに対して時刻を返信するTwitter botを作ってみます。「今何時」以外のつぶやきが来た場合は返信しません。

twitter = require "ntwitter"

twit = new twitter
  consumer_key       : "CONSUMER_KEY"
  consumer_secret    : "CONSUMER_SECRET"
  access_token_key   : "ACCESS_TOKEN"
  access_token_secret: "ACCESS_TOKEN_SECRET"

# 自分のTwitter IDを取得する
twit.verifyCredentials (err, data) ->
  if err then throw err
  user_id_str = data.id_str

  # userストリームに接続する
  twit.stream "user", (stream) ->
    console.log "ready"
    stream.on "data", (data) ->  # 新しいデータが来た
      if data.in_reply_to_user_id_str is user_id_str  # @付きのつぶやきが来た
        console.log "new mention from @#{data.user.screen_name}: #{data.text}"

        # 本文から@usernameを取り除く
        text = data.text.replace /^@\w+\S+/, ""

        reply = null
        if /今何時/.test text
          d = new Date
          reply = "#{d.getHours()}時#{d.getMinutes()}分だよ"
        if reply?
          reply = "@#{data.user.screen_name} #{reply}"
          console.log "update: #{reply}"

          # つぶやく
          twit.updateStatus reply, {
            in_reply_to_status_id: data.id_str
          }, (err, data) ->
            if err
              console.log "update error: #{err}"
            else
              console.log "update success"

天気予報を取得する

まずrequestモジュールをインストールします。

$ npm install request

Livedoorお天気Webサービスを使って、簡単に天気予報を取得できます。

request = require "request"

# cityId一覧: http://weather.livedoor.com/forecast/rss/primary_area.xml
cityId = "130010"  # 東京

apiUrl = "http://weather.livedoor.com/forecast/webservice/json/v1?city=#{cityId}"

# URLにアクセスしてデータを取得する
request apiUrl, (err, response, body) ->
  if err  # プログラムエラー
    throw err

  if response.statusCode is 200  # 取得成功
    # JSONとして解釈する
    try
      json = JSON.parse body
    catch e
      console.log "JSON parse error: #{e}"

    # 直近の予報データを取得
    forecast = json.forecasts[json.forecasts.length-2]

    # 文を作る
    weather = "#{json.location.city}の#{forecast.dateLabel}の天気は#{forecast.telop}"
    if forecast.temperature.max?  # 気温情報がある場合
      weather += "、最高気温は#{forecast.temperature.max.celsius}度、" + \
        "最低気温は#{forecast.temperature.min.celsius}度"
    weather += "です。"
    console.log weather
  else  # APIレスポンスエラー
    console.log "Response error: #{response.statusCode}"

【実行結果】

東京の明日の天気は晴のち曇、最高気温は35度、最低気温は26度です。